TRANSRAZ

Querying the TRANSRAZ Knowledge Graph

Please use the following prefixes for the queries below:

PREFIX transraz: <http://toporaz.de/ontology/2022/11/owl/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dbo: <http://www.dbpedia.org/ontology/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX oa: <http://www.w3.org/ns/oa#>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX cidoc: <http://cidoc-crm.org/cidoc-crm/7.1.2/>

Category 1: Ancestor Search

Users with ancestors in Nuremberg have the possibility to explore, where their relatives lived, how they lived and what their neighborhood looked like.

Query 1: What information is available for family or namesakes with last name 'Ruppert' living in the city?

Show Query Result


SELECT ?name ?predicate ?objectL
WHERE { 
    ?person rdf:type dbo:Person ;
        foaf:familyName "Ruppert" ;
        rdfs:label ?name  ;
        ?predicate ?object .
    OPTIONAL {?object rdfs:label ?objectL}
    FILTER isLiteral(?objectL)}

Query 2: Show all people who lived under address "Engelsgasse 17". If available, show more specific information about the addresses, e.g. floor.

Show Query Result


SELECT DISTINCT ?name  ?addressName 
WHERE { 
    ?activity transraz:associatedWithAddress ?address ;
        cidoc:P14_carried_out_by ?person ;
        transraz:time ?time .
    ?time rdfs:label "[1908]" .
    ?person rdfs:label ?name .
    ?address rdfs:label ?addressName .
    ?buildingPart rdf:type transraz:BuildingPart ;
        rdfs:label ?addressName . 

    OPTIONAL { ?buildingPart transraz:buildingpartComposedOf ?builPart .
           ?builPart rdf:type transraz:BuildingPart ;
                rdfs:label  ?partAddName .}
    {?builPart transraz:buildingpartComposedOf ?building} 
    UNION 
    {?buildingPart transraz:buildingpartComposedOf ?building} .
    ?building rdf:type transraz:Building ;
        rdfs:label "Engelsgasse 17"}

Query 3: What did the Karlsbrücke street look like in the past? What kind of industries were based there?

Show Query Result


SELECT ?branchName (COUNT(?branchName) as ?frequency)
WHERE {
    ?company rdf:type dbo:Organisation ;
             transraz:branch?branch ;
             transraz:address ?address .
    ?address rdfs:label ?addressName . 
    ?building rdf:type transraz:Building ;
              rdfs:label ?addressName ;
              transraz:streetAddress ?street .
    ?street rdfs:label "Karlsbrücke" .
    ?branch rdfs:label ?branchName . }
GROUP BY ?branchName
ORDER BY DESC(?frequency)

Category 2: Wealth Distribution

Users with ancestors in Nuremberg have the possibility to explore, where their relatives lived, how they lived and what their neighborhood looked like.

Query 1: Which properties and real estates belonged to a family or namesakes Pirner and how did they distribute throughout the city?

Show Query Result


SELECT ?ownerName ?buildingName 
WHERE {
    ?owner  dbo:owner ?address   ;
            rdfs:label   ?ownerName ;
            foaf:familyName "Pirner".
    ?address    rdfs:label ?addressName .
    ?buildingPart   rdf:type transraz:BuildingPart ;
                    rdfs:label ?addressName ;
                    transraz:buildingpartComposedOf ?building .
    ?building   rdf:type transraz:Building ;
                rdfs:label ?buildingName ;
                transraz:streetAddress ?street .
    ?street rdfs:label ?streetName. }

Query 2: Who owned properties and real estates in the Friedenstraße?

Show Query Result


SELECT ?ownerName ?buildingName
WHERE {
    ?owner dbo:owner ?address   ;
               rdfs:label   ?ownerName .
    ?address rdfs:label ?addressName .
    ?buildingPart rdf:type transraz:BuildingPart ;
                  rdfs:label ?addressName ;
                  transraz:buildingpartComposedOf ?building .
    ?building   rdf:type transraz:Building ;
                rdfs:label ?buildingName ;
                transraz:streetAddress ?street .
    ?street rdfs:label "Friedenstraße". }
ORDER BY ?buildingName

Query 3: Where did teachers ("Lehrer") of Nuremberg live?

Show Query Result


SELECT ?streetName (COUNT(?streetName) as ?frequency)
WHERE {
    ?person dbo:profession ?occupation ;
            transraz:address ?address.
    ?occupation rdfs:label "Lehrer" . 
    ?address rdfs:label ?addressName .
    ?buildingPart rdf:type transraz:BuildingPart ;
                  rdfs:label ?addressName ;
                  transraz:buildingpartComposedOf ?building .
    ?building rdf:type transraz:Building ;
              rdfs:label ?buildingName ;
              transraz:streetAddress ?street .
    ?street rdfs:label ?streetName. }
GROUP BY ?streetName
ORDER BY DESC(?frequency)

Query 4: Where did breweries ("Bierbrauerei") establish?

Show Query Result


SELECT ?streetName (COUNT(?streetName) as ?frequency)
WHERE {
    ?company transraz:branch ?branch ;
             transraz:address ?address .
    ?branch rdfs:label "Bierbrauerei". 
    ?address rdfs:label ?addressName .
    ?building rdf:type transraz:Building ;
              rdfs:label ?addressName ;
              transraz:streetAddress ?street .
    ?street rdfs:label ?streetName. }
GROUP BY ?streetName
ORDER BY DESC(?frequency)

Category 3: Change and Events

Researchers interested in the transformation of the city and changes of entities can explore the movement of a person within the city over the years, the destruction and construction of architectural objects and social events taking place.

Query 1: Where did Georg Philipp Höfler live in the city throughout time?

Show Query Result


SELECT ?personName  ?addressLabel ?timeLabel 
WHERE {
    ?person rdfs:label "Georg Philipp Höfler" ;
            rdfs:label ?personName .
    ?activity cidoc:P14_carried_out_by ?person ;
              transraz:associatedWithAddress ?address ;
              transraz:time ?time .
    ?time rdfs:label ?timeLabel .
    ?address rdfs:label ?addressLabel .}

Query 2: Where were the schools located in 1908 and how did the school establishment of Nuremberg develop throughout time?

Show Query Result


SELECT ?schoolLabel ?addressLabel ?foundingTimeLabel
WHERE {
    ?school transraz:branch ?branch ;
            rdfs:label ?schoolLabel .
    ?branch rdfs:label "Schule" .
    ?activity cidoc:P14_carried_out_by ?school ;
              transraz:time ?time ;
              transraz:associatedWithAddress ?address .
    ?time rdfs:label "[1908]".
    ?address rdfs:label ?addressLabel .
    OPTIONAL  {?school transraz:foundingPeriod ?foundingTime .
    ?foundingTime rdfs:label ?foundingTimeLabel .}}

Category 4: Social and Cultural

To learn about the social life of the historical city over the years, users are able to explore touristic and culturally important areas.

Query 1: What were the main cultural areas in the city, e.g. cultural and art institutions?

Show Query Result


SELECT ?organisationLabel ?addressLabel
WHERE {
?organisation transraz:branch ?branch ;
              rdfs:label ?organisationLabel ;
              transraz:address ?address .
?address rdfs:label ?addressLabel .
?branch rdfs:label "Kunstanstalt".
}

Query 2: In which parts of the city did most artists live?

Show Query Result


SELECT ?streetName (COUNT(?streetName) as ?frequency)
WHERE {
    ?person dbo:profession ?profession ;
            transraz:address ?address .
    ?address rdfs:label ?addressName .
    ?buildingPart rdf:type transraz:BuildingPart ;
                  rdfs:label ?addressName ;
                  transraz:buildingpartComposedOf ?building .
    ?building rdf:type transraz:Building ;
              rdfs:label ?buildingName ;
              transraz:streetAddress ?street .
    ?street rdfs:label ?streetName.
    ?profession rdfs:label ?profLabel .
    FILTER regex( str(?profLabel), "[Aa]rchitekt|[Mm]aler|[Kk]unstler|[Aa]rtist|[Ss]tifter|[Mm]usik|[Ss]teinmeißel|[Bb]ildhauer|[Kk]unst|[Gg]ravier") }
GROUP BY ?streetName
ORDER BY DESC(?frequency)

Category 5: Historical Sources and Provenance

Researchers can verify findings presented in the VRE by directly exploring the connected historical source documents. Furthermore, document annotations and their origins can be reproduced.

Query 1: What historical literature mentiones Friendenstraße?

Show Query Result


SELECT DISTINCT ?documentLabel
WHERE {
    ?street rdf:type dbo:Street  ;
            rdfs:label ?streetLabel ;
            rdfs:label "Friedenstraße" .
    ?annotation oa:hasTarget ?page ;
                oa:hasBody ?street .
    ?document frbr:part ?page ;
              rdfs:label ?documentLabel . }

Query 2: Where can be information about Friedenstraße be found in a historical resource, e.g. page number or coordinates?

Show Query Result


SELECT DISTINCT ?streetLabel ?pageLabel ?coordinates
WHERE {
    ?street rdf:type dbo:Street  ;
            rdfs:label ?streetLabel ;
            rdfs:label "Friedenstraße" .
    ?annotation oa:hasTarget ?page ;
                oa:hasBody ?street ;
                transraz:altoCoordinates ?coordinates.
    ?page rdfs:label ?pageLabel . }

Query 3: What types of documents mention Friedenstraße?

Show Query Result


SELECT DISTINCT ?documentType ?bookType
WHERE {
    ?street rdf:type dbo:Street  ;
            rdfs:label ?streetLabel ;
            rdfs:label "Friedenstraße" .
    ?annotation oa:hasTarget ?page ;
                oa:hasBody ?street .
    ?book frbr:part ?page ;
          rdf:type ?bookType .
    ?document fabio:hasManifestation ?book ;
              rdf:type ?documentType . }

Query 4: How and when were the annotations of Friedenstraße created? Manually or automatically?

Show Query Result


SELECT DISTINCT ?streetLabel ?pageLabel ?annotationCreator ?date 
WHERE {
    ?street rdf:type dbo:Street  ;
            rdfs:label ?streetLabel ;
            rdfs:label "Friedenstraße" .
    ?annotation oa:hasTarget ?page ;
                oa:hasBody ?street ;
                dcterms:creator ?annotationCreator ;
                dcterms:created ?date .
    ?page rdfs:label ?pageLabel . }